Announcement

**Deviant Ollam** · February 18, 2006, 18:24

when you refer to "what you've added to the system" what exactly do you mean? the software you've installed or the documents and other files that you've created? if you wish to keep a backup of the system as it is loaded and configured right now, software included, you need to do a full ghost image or other such backup. you can't just backup the program directories since, unlike *nix O/S environments, program configs aren't kept in basic text files within the program dir... there are windows registry components and system DLLs, etc. to back up software, you're better raw-imaging the whole drive.

to backup just your documents and other data, command.com in conjunction with rar.exe works very well... write yourself a batch file that looks something like this...

Code:

@ECHO OFF

REM   this is a backup tool that i have written which will add the
REM   contents of any directory or directories that you wish into
REM   large RAR archives.  this tool uses two DOS utilities, both of
REM   which are freeware. RAR.exe creates compressed archives.
REM   FSUM.EXE is a CRC file checker.

REM   the following is an example of a backup where files from a
REM   directory called "documents" on the c: drive are being
REM   archived to a removable disk or removable hard drive with
REM   a drive letter of "e"

REM   ---------------------------------------------------------------

REM   to completely clear off the destination media (in this case
REM   the e: drive) of any old files this delete command is used.
REM   preceeding the delete all command with an "echo y" and a
REM   pipe character is a way to automatically pass the answer of
REM   "yes" to the quesion that the delete command is going to
REM   ask, namely "are you sure you want to do this?"

echo y|del e:\*.*

REM   ---------------------------------------------------------------

REM   here we establish a backup.txt log file on the now freshly-
REM   cleaned backup media.  this file is added to using the double
REM   output mark ">>" which appends a command's output to a
REM   file.  the single ">" character will overwrite the existing file,
REM   hence a double character is used in all except the first instance

ECHO. |DATE > e:\backup.txt
ECHO. >> e:\backup.txt
ECHO. |TIME >> e:\backup.txt
ECHO Backup Started >> e:\backup.txt

REM   ---------------------------------------------------------------

REM   the following code assumes that you wish to backup a
REM   directory on the c: drive called "documents" and place
REM   this backup in a RAR file called "docs.rar" on the e: drive.
REM   first we change directories into the one with the files
REM   wanted, then we initiate a RAR command.  the command
REM   used after the RAR phrase is "a" meaning "archive." the
REM   switches used on the RAR command include...
REM   
REM   -y  this is a "yes" to all questions that RAR may ask, making
REM   the process automatic
REM   -r  this is to "recurse" all sub-directories
REM   -m3 this is the compression setting.  RAR.exe may work on
REM   compression levels 1 through 5 with 1 being the fastest but
REM   least compressed and 5 being very slow but providing excellent
REM   compression
REM   -v  creates volume spanning.  in this case, the volumes would
REM   be 15 megabytes in size.
REM
REM   a switch that isn't listed here but can be of use to some people
REM   is the "-dh" switch. this allows RAR to open shared files which
REM   other users are accessing.  it is not a perfect operation, but
REM   can avoid the problem of files not being backed up if, say, a user
REM   is working in QuickBooks while the backup is running.

c:
cd\
cd documents
rar a -y -r -m3 -v15000 e:\docs.rar c:\documents\*.*

REM   ---------------------------------------------------------------

REM   after the RAR operation completes, i find it just good policy
REM   to include another date stamp in the backup.txt file as it
REM   serves as a record for how long the process took, etc.  this
REM   can be useful in calculating average run times and deciding
REM   whether to, say, run a backup mid day if the staff is out for
REM   a break, etc.

ECHO. >> e:\backup.txt
ECHO. |TIME >> e:\backup.txt
ECHO Backup Completed >> e:\backup.txt

REM   ---------------------------------------------------------------

REM   and this step is the creation of the CRC checksum for
REM   verifying archive integrity

ECHO.
ECHO Creating CRC Checksum SFV File
ECHO.
e:
cd\
fsum -crc32 -js *.r* > docs.sfv

REM   ---------------------------------------------------------------

ECHO Backup Complete.
PAUSE
EXIT

if you'd like them, here are rar and fsum. they should work under nearly all DOS environments and win9x/winnt command prompts.

i wrote that to be pretty idiot-proof back when i was working for a medical office some time ago. i think it was a win9x environment... under win2k the del command wouldn't be used to wipe the destination media (and i don't think you can pipe a "yes" answer like that in the winnt command prompt anyway) but you'd instead use a format command with the "force" switch of /f. tinker with it, try to see what works for you, adjust paths as necessary. ymmv.

p.s. - the date and time and time commands work differently under winnt. you'd use the /t switch to just output the value as opposed to using a pipe.

**arashi_kage** · February 19, 2006, 08:26

Thanks a lot

1st let me say as I move from lurking to making my first post, your response was way better than I expected. Thank you Deviant.

when you refer to "what you've added to the system" what exactly do you mean? the software you've installed or the documents and other files that you've created?

I was mainly speaking of the documents and Java and VB6 programs I wrote, music & video stuff.

to backup just your documents and other data, command.com in conjunction with rar.exe works very well... write yourself a batch file that looks something like this...

I already have a .rar program. I have been thinking about doing more with batch writing so this looks like a good time to start.

**Deviant Ollam** · February 19, 2006, 17:04

Originally posted by arashi_kage

1st let me say as I move from lurking to making my first post, your response was way better than I expected. Thank you Deviant.

my pleasure to help. thank you for making such a great first post. you came, you lurked, you learned, you googled for some info beforehand, you expressed in pretty clear terms the direction you wanted to go with a task and some leads you had dug up. it's a pleasure to help someone who shows the signs that something good will come of their efforts.

Originally posted by arashi_kage

I have been thinking about doing more with batch writing so this looks like a good time to start.

sweet. one of the best skills to have is the ability to knock together batch files or shell scripts. i know of networks where like three fourths of the entire maintenance and operation is done with scripting as opposed to high-end, expensive packages from software vendors. document your code so that those who come after you can follow what's going on and your department will run smoothly and under budget almost all the time.

best of luck with your batch writing. feel free to check back if you hit bumps in the road that prove difficult to surmount.

**haden** · February 19, 2006, 21:54

the best place to get good freeware for windows that i have foundis to just go out and buy the latest issue of maximum pc. It comes with a cd with all sorts of apps and utilities. Last months issue had a good back up program on it. dont remember the name but every thing that comes on the disk is either freeware or trialsand theirs a few demos each month of the latest games and older strategy games like alchemy

**justjake** · February 20, 2006, 10:08

In order to do a real simple backup, I use karens replicator.
Its free. Its simple.

http://www.karenware.com/powertools/ptreplicator.asp

Announcement

System Backups

System Backups

Comment

Comment

Comment

Comment

Comment